Pascal/Istruzioni di controllo

Strutture di selezione

Selezione binaria

In alcuni degli esempi precedenti si è analizzata la struttura if...then...else; vediamo nello specifico in cosa consiste.

Nella pratica, questo costrutto consente la scelta fra due alternative: se (if) una certa condizione è vera allora (then) il programma esegue una certa istruzione (semplice o composta), altrimenti (else) ne esegue un'altra:

if condizione  then istruzione
       else istruzione;

che come abbiamo già visto permette la scelta fra un caso vero e un caso falso e in base a questo esegue il contenuto del then o dell'else; tuttavia a volte il ramo in else non é; strettamente utile o addirittura non serve.

Quando le istruzioni che seguono il then o l'else sono più di una esse devono essere delimitate da istruzioni begin e end (sono istruzioni composte):

if condizione then
begin
    istruzione 1;
    istruzione 2;
    ...
    istruzione n
end
else
begin
    istruzione 1;
    istruzione 2;
    ...
    istruzione n
end;

Si noti come le istruzioni che precedono end ed else non debbano essere seguite da punto e virgola

Facciamo un esempio pratico.
Si vuole calcolare la radice quadrata di un numero: ciò è possibile nell'insieme dei numeri reali solo se il valore in ingresso è positivo. Il programma deve perciò:

• acquisire il numero
• eseguire una selezione binaria: se il numero è positivo,allora ne calcola la radice quadrata e espone il risultato;altrimenti stampa un messaggio di errore;

program radice_quadrata;
    var n,r:real;
begin
    writeln('Inserisci un numero positivo');
    readln(n);
    if n>=0 then
    begin
       r:=sqrt(n);
       writeln('La radice quadrata del numero inserito e'' ',r:8:3);
    end
    else
       writeln('La radice di un numero negativo non può essere espressa con numeri reali');
    readln; (* attenzione: questo readln non fa parte del blocco else! *)
end.

Selezione multipla

Con l'uso del costrutto case... of è possibile eseguire selezioni più complesse. La sintassi è:

case espressione of
     valore 1 : begin 
                    istruzioni;
                end;
     valore 2 : begin
                    istruzioni;
                end;
     ... 
     
     valore n : begin
                    istruzioni
                 end; 
  
     else        begin
                    istruzioni;
                 end;
end;

Con il costrutto case, il valore dell'espressione in testa viene confrontato con il valore di ogni singolo caso; quando viene trovato un valore che soddisfa le condizioni sul selettore vengono eseguite le istruzioni relative al blocco in questione; poi il controllo passa alla prima istruzione dopo il costrutto case. Se nessun valore soddisfa il selettore viene eseguita l'ultimo blocco di istruzioni individuato dalla parola chiave else (se questo blocco è stato inserito). Se la parte con else viene omessa e il selettore non eguaglia nessuno dei casi in elenco, si passa anche in questo caso alla prima istruzione dopo il costrutto case.

Quando c'è solo un'istruzione che segue un certo caso si possono omettere begin e end (questo perché, in realtà, le istruzioni delimitate da begin ed end si possono considerare come un'unica istruzione).

Occorre fare attenzione che il costrutto case termina con un end. Facciamo un esempio del costrutto case:

case contatore of
  1, 2, 50, 210: writeln(contatore);
  30, 60..80 : begin
                 writeln(variabile); 
               end;
end;

Ecco di seguito alcune considerazioni sull'esempio proposto:

• è stata omesso il blocco facoltativo else
• sono state indicate delle liste di possibili casi
• è stato usato un range di valori x..y; al terzo rigo,60..80 indica tutti i valori compresi tra 60 e 80 (inclusi).

Strutture Iterative

In Pascal abbiamo diversi tipi di strutture iterative (in genere vengono detti "cicli"). Una struttura iterativa prevede la ripetizione di un'istruzione semplice o composta secondo delle condizioni poste all'inizio o alla fine della struttura.

Iterazione con contatore

Questa struttura ci permette di ripetere una determinata serie di istruzioni per un numero finito di volte modificando man mano il valore di una variabile. La sua sintassi è:

for Contatore:=valore_iniziale to valore_finale do
begin
  istruzione 1;
  istruzione 2;
  ...
  istruzione n;
end;

Nella pratica questo costrutto consente la ripetizione di un certo gruppo di istruzioni fino a quando la variabile contatore raggiunge un certo valore: per (for) contatore:=valore_iniziale fino a (to) valore_finale esegui (do) un blocco d'istruzioni racchiuso tra begin ed end.

Contatore è una variabile (di solito vengono usate le lettere I,L,M,N,J,K) che da un valore iniziale cresce di un'unità ad ogni ripetizione fino a che non raggiunge il valore finale, che rappresenta il valore per il quale il ciclo terminerà.

L'iterazione può anche procedere in modo che la variabile contatore decresca a ogni ciclo; in questo caso la sintassi è:

for Contatore:=valore_iniziale downto valore_finale do
begin
  istruzione 1;
  istruzione 2;
  ...
  istruzione n;
end;

Facciamo un esempio: implementiamo un programma che calcoli la somma dei primi n numeri naturali usando un ciclo for (senza usare la nota formula ${\frac {n(n+1)}{2}}$).
Il programma deve:

• leggere n;
• tramite un ciclo for, sommare tutti i numeri da 1 a n;
• esporre il risultato.

program sommatoria;
    var i,n,s:integer;
begin
    s:=0;
    writeln('Inserisci n');
    readln(n);
    for i:=1 to n do
        s:=s+i;
    writeln('La somma dei primi n è ',s);
    readln;
end.

Analizziamo il programma riga per riga:

• dichiarazione del programma;
• dichiarazione delle variabili: i è la variabile contatore, n funge da valore finale del ciclo for, q è di volta in volta il quadrato di i mentre s è la somma dei numeri naturali fino a n;
• inizio del programma
• la somma è inizialmente uguale a 0;
• messaggio di testo;
• il programma legge n;
• il ciclo for: per i uguale a 1 fino a che i non sia uguale a n,esegue il gruppo d'istruzioni:
• inizio del ciclo;
• alla variabile s viene assegnata la somma del valore di s+i; prima del ciclo s era uguale a 0, quindi s:=1;
• fine del ciclo: se i è diverso da n, il ciclo viene riavviato; altrimenti si prosegue all'istruzione successiva. Automaticamente alla fine del ciclo i viene incrementato di 1.

Vediamo cosa succede se n assume ad esempio il valore 50:

• i := 2, diverso da 50, quindi il ciclo continua;
• s := s + i, cioè s:=1+2; infatti la variabile s aveva valore 1 alla fine della prima fase del ciclo.
• ricomincia il ciclo; i:=3,diverso da 50,quindi il ciclo continua;
• s := s + i;cioè s := 3 + 3;
• e così via, fino a quando i sia diverso da 50.

Iterazione con condizione in testa

Una struttura di iterazione con condizione in testa è tradotta in Pascal con il ciclo while... do La sua sintassi è:

while condizione do
begin
    istruzione 1;
    istruzione 2;
    ...
    istruzione n;
end;

Ovvero: mentre (while) una determinata condizione è vera esegui (do) le istruzioni all'interno del ciclo.

Fino a quando la condizione è vera, il ciclo viene eseguito. Tra begin ed end vanno inserite le istruzioni che cambiano in qualche modo il valore di verità della condizione. Questo è molto importante perché altrimenti il ciclo si ripeterebbe all'infinito e il programma non riuscirebbe mai a giungere alle righe che seguono l'istruzione end. Questo è un comune errore che con un po' di attenzione può essere evitato. Se vi è una sola istruzione begin e end possono essere omessi. Ad esempio:

...
x:=1;
while x<>5 do
    x:=x+1;
...

In questo esempio viene eseguito quanto indicato all'interno del ciclo finché viene verificata la condizione, cioè ad x viene sommato 1 fino a che il suo valore non sia uguale a 5,e quindi la condizione iniziale del ciclo diventi falsa.

Iterazione con condizione finale

Per chiudere il discorso riguardo alle strutture di controllo analizziamo il ciclo con condizione finale, che in Pascal si traduce con un ciclo repeat... until

La sua sintassi e':

 
repeat
begin
    istruzione 1; 
    istruzione 2;
    ... 
    istruzione n
end;
until condizione;

In sostanza questo ciclo ripete le istruzioni comprese tra Repeat ed Until (dall'inglese,finché) fino al verificarsi della condizione espressa, detta anche condizione di uscita. Anche in questo caso occorre porre attenzione al fatto che la condizione di uscita diventi vera in qualche modo, altrimenti finiamo in un loop infinito perdendo il controllo del programma.

Ad esempio:

x:=1;
repeat
x:=x+1;
until x=5;

In questo caso x viene sommato a 1 fino a che il suo valore non sia diverso da 5; quando x=5 si esce dal ciclo.

Un confronto

Nel caso del ciclo For il numero di cicli eseguiti è noto, poiché il contatore parte da un elemento iniziale ed arriva fino all'elemento finale. Nel caso di While e di Repeat Until il numero di volte che viene ripetuto il ciclo generalmente non è noto a priori, in quanto dipende dal cambiamento che subisce la variabile che controlla la condizione.

È importante notare che le istruzioni del ciclo Repeat Until verranno eseguite almeno una volta poiché la condizione viene verificata alla fine, dopo il codice del ciclo; un ciclo While, essendo la sua condizione testata prima dell'esecuzione del codice associato al ciclo, potrebbe, se questa risulta falsa, non fare nulla e riprendere dalle istruzioni che si trovano dopo il ciclo. Questo può risultare utile in particolari casi come in altri può essere causa di bug.

Esercizi

• Scrivere un programma che stampi la tabellina del numero immesso dall'utente

Soluzione proposta

program tabelline;
uses crt;
var tab, i, ris: integer;
begin
    clrscr;
    write('Che tabellina vuoi che ti stampi? '); readln(tab);
    for i:=0 to 10 do
    begin
        ris:=tab*i;
        writeln(tab, ' x ', i, ' = ', ris );
    end;
    readln;
end.

• Scrivere un programma "indovina il numero". Il programma deve chiedere all'utente un numero, scegliere casualmente un numero tra 1 e il numero fornito. L'utente dovrà quindi indovinare il numero pensato dal computer: ad ogni tentativo, il computer deve dire se il tentativo è maggiore o minore del numero pensato.

Soluzione proposta

program indovina;
var max, x, t: integer;
begin
    randomize;
    write('Per inizializzare il gioco, scegli il limite massimo: '); readln(max);
    x := trunc(random() * max) + 1;

    repeat
        write(' >>> '); readln(t);
        if t > x then
            writeln(t, ' e'' troppo grande! Riprova');
        if t < x     then
            writeln(t, ' e'' troppo piccolo! Riprova');
        if t = x then
            writeln('Complimenti! ', t, ' e'' il numero esatto!');
    until t = x;
    readln;
end.

Rappresentazione grafica del metodo Monte Carlo applicato al calcolo di $\pi$

• Scrivere un programma per il calcolo di $\pi$ usando il metodo Monte Carlo. Questo metodo consiste nell'estrarre casualmente dei punti all'interno di un quadrato e valutare se questi sono interni od esterni all'arco di ampiezza ${\pi \over 4}$ inscritto nel quadrato.
  Consigli: considerare un quadrato di raggio unitario; dato il punto di coordinate x e y, questo si trova dentro al cerchi se vale la relazione ${\sqrt[{2}]{x^{2}+y^{2}}}<1$.

Per approfondire su Wikipedia, vedi la voce Metodo Monte Carlo.

Soluzione proposta

{CALCOLA il valore di pigreco usando il metodo di montecarlo}
program pigreco;
uses crt;
var i, n, dentro : integer;
    x, y , pi : real;
begin
    randomize;
    clrscr;
    
    write('Quanti punti vuoi estrarre? ');
    readln(n);

    dentro:=0;
    for i := 1 to n do
    begin
        {estrae un punto nel quadrato di raggio unitario}
        x:=random();
        y:=random();
        if (x*x + y*y) < 1 then
            dentro:=dentro + 1;
    end;

{abbiamo valutato un quarto di cerchio}
writeln('Valore approssimato di pi greco: ', (4 * dentro / n):10:8);
readln;
end.

• Scrivere un programma per determinare il valore di un radicale tramite tentavi successivi, in questo modo: il programma chiede con quale indice si vuole lavorare; successivamente, chiederà all'utente un'approssimazione della radice, e mostrerà la potenza del numero immesso secondo l'indice. In questo modo, in base al valore della potenza, l'utente potrà ritentare proponendo un numero maggiore o minore di quello immesso. Il programma termina quando l'utente immette 0.

Esempio: si supponga si voglia trovare con tentativi successivi il valore della radice quadrata di 5. Si sceglierà innanzitutto di lavorare con indice 2, quindi si immette il primo tentativo (ad esempio 2). Il programma stamperà 4, che è troppo basso: serve un numero più alto. Immettendo 3 si ottiene 9, che è troppo alto: la radice del numero cercato sarà quindi compresa tra 2 e 3; immettiamo ad esempio 2.5. Il risultato è ancora troppo alto, immettiamo quindi 2.3: otteniamo 5.29, ancora troppo alto. Immettendo 2.2 otteniamo invece un numero più basso di due. Il numero cercato è quindi compreso tra 2.2 e 2.3, e così via...

Soluzione proposta

program radici;
uses crt;
var num, ris: real;
    exp, i: integer;
begin
    clrscr;
    write('Con che indice vuoi lavorare? ');
    readln(exp);
    writeln();
    writeln('Inserire un''approssimazione della radice');
    writeln('Per uscire dal programma digitare 0');
    writeln;
    repeat
        readln(num);
        ris := 1;
        for i:=1 to exp do
            ris:=ris * num;
        writeln(ris:1:10);
        writeln;
    until num=0;
end.

• Scrivere una funzione che restituisca la posizione di un carattere chiesto all'utente nella stringa chiesta anch'essa all'utente. La posizione deve essere quella della prima occorrenza trovata.

Soluzione proposta

program strpos;
uses crt;
var str: string[100];
    ch : char;
    i, pos : integer;
    trovato : boolean;
begin
    clrscr;
    write('Cerca nella stringa: '); readln(str);
    write('il carattere:        '); readln(ch);
    trovato := false;
    for i := 1 to length(str) do
    begin
        if (trovato = false) and (str[i] = ch) then
        begin
            pos := i;
            trovato := true;
        end;
    end;
    if trovato = true then
        writeln('Il carattere ', ch, ' si trova alla posizione ', pos:2)
    else
        writeln('Nella stringa non e'' presente il carattere cercato');
    readln;
end.